Arduino - 字符串

字符串用于存储文本。它们可用于在 LCD 或 Arduino IDE 串行监视器窗口中显示文本。字符串对于存储用户输入也很有用。例如，用户在连接到 Arduino 的键盘上键入的字符。

Arduino 编程中有两种类型的字符串 -

  • 字符数组，与 C 编程中使用的字符串相同。
  • Arduino String，它允许我们在草图中使用字符串对象。

在本章中，我们将学习字符串、对象以及字符串在 Arduino 草图中的使用。在本章结束时，您将了解在草图中使用哪种类型的字符串。

字符串字符数组

我们将学习的第一种字符串类型是由一系列char类型的字符组成的字符串。在上一章中，我们学习了什么是数组；存储在内存中的连续一系列相同类型的变量。字符串是 char 变量的数组。

字符串是一种特殊的数组，在字符串末尾有一个额外的元素，该元素的值始终为 0（零）。这称为“空终止字符串”。

字符串字符数组示例

此示例将展示如何创建字符串并将其打印到串行监视器窗口。

例子

void setup() {
   char my_str[6]; // an array big enough for a 5 character string
   Serial.begin(9600);
   my_str[0] = 'H'; // the string consists of 5 characters
   my_str[1] = 'e';
   my_str[2] = 'l';
   my_str[3] = 'l';
   my_str[4] = 'o';
   my_str[5] = 0; // 6th array element is a null terminator
   Serial.println(my_str);
}

void loop() { 

}

以下示例显示了字符串的组成部分；一个包含可打印字符的字符数组，0 作为数组的最后一个元素，以表明这是字符串的结束位置。通过使用Serial.println()并传递字符串名称，可以将该字符串打印到 Arduino IDE 串行监视器窗口。

这个相同的例子可以用更方便的方式编写，如下所示 -

例子

void setup() {
   char my_str[] = "Hello";
   Serial.begin(9600);
   Serial.println(my_str);
}

void loop() {

}

在此草图中，编译器计算字符串数组的大小，并自动使用 null 以零终止字符串。创建一个长度为六个元素、由五个字符后跟一个零组成的数组，其创建方式与上一个草图完全相同。

操作字符串数组

我们可以更改草图中的字符串数组，如下图所示。

例子

void setup() {
   char like[] = "I like coffee and cake"; // create a string
   Serial.begin(9600);
   // (1) print the string
   Serial.println(like);
   // (2) delete part of the string
   like[13] = 0;
   Serial.println(like);
   // (3) substitute a word into the string
   like[13] = ' '; // replace the null terminator with a space
   like[18] = 't'; // insert the new word
   like[19] = 'e';
   like[20] = 'a';
   like[21] = 0; // terminate the string
   Serial.println(like);
}

void loop() {

}

结果

I like coffee and cake
I like coffee
I like coffee and tea

草图按以下方式工作。

创建并打印字符串

在上面给出的草图中，创建了一个新字符串，然后打印该字符串以显示在串行监视器窗口中。

缩短字符串

通过将字符串中的第 14 个字符替换为以零结尾的 null (2)，可以缩短字符串。这是字符串数组中从 0 开始计数的第 13 个元素。

打印字符串时，所有字符都会打印到以零结尾的新空值。其他角色并没有消失；它们仍然存在于内存中，并且字符串数组的大小仍然相同。唯一的区别是任何处理字符串的函数都只会看到第一个空终止符之前的字符串。

更改字符串中的单词

最后，草图将“蛋糕”一词替换为“茶”(3)。它首先必须用空格替换 like[13] 处的空终止符，以便字符串恢复为最初创建的格式。

新字符用单词“tea”覆盖单词“cake”中的“cak”。这是通过覆盖单个字符来完成的。“cake”的“e”被替换为新的空终止字符。结果是字符串实际上以两个空字符终止，原始字符位于字符串末尾，新字符替换“cake”中的“e”。当打印新字符串时，这没有什么区别，因为打印字符串的函数在遇到第一个空终止符时会停止打印字符串字符。

操作字符串数组的函数

前面的草图通过访问字符串中的各个字符以手动方式操作字符串。为了更轻松地操作字符串数组，您可以编写自己的函数来执行此操作，或者使用C语言库中的一些字符串函数。

下一个草图使用一些 C 字符串函数。

例子

void setup() {
   char str[] = "This is my string"; // create a string
   char out_str[40]; // output from string functions placed here
   int num; // general purpose integer
   Serial.begin(9600);

   // (1) print the string
   Serial.println(str);

   // (2) get the length of the string (excludes null terminator)
   num = strlen(str);
   Serial.print("String length is: ");
   Serial.println(num);

   // (3) get the length of the array (includes null terminator)
   num = sizeof(str); // sizeof() is not a C string function
   Serial.print("Size of the array: ");
   Serial.println(num);

   // (4) copy a string
   strcpy(out_str, str);
   Serial.println(out_str);

   // (5) add a string to the end of a string (append)
   strcat(out_str, " sketch.");
   Serial.println(out_str);
   num = strlen(out_str);
   Serial.print("String length is: ");
   Serial.println(num);
   num = sizeof(out_str);
   Serial.print("Size of the array out_str[]: ");
   Serial.println(num);
}

void loop() {

}

结果

This is my string
String length is: 17
Size of the array: 18
This is my string
This is my string sketch.
String length is: 25
Size of the array out_str[]: 40

草图按以下方式工作。

打印字符串

新创建的字符串将打印到串行监视器窗口，如前面的草图所示。

获取字符串的长度

strlen()函数用于获取字符串的长度。字符串的长度仅适用于可打印字符，不包括空终止符。

该字符串包含 17 个字符，因此我们在“串行监视器”窗口中看到打印的 17。

获取数组的长度

运算符 sizeof() 用于获取包含字符串的数组的长度。长度包括空终止符，因此长度比字符串的长度多一。

sizeof() 看起来像一个函数，但从技术上讲它是一个运算符。它不是 C 字符串库的一部分，但在草图中用于显示数组大小和字符串大小（或字符串长度）之间的差异。

复制字符串

strcpy() 函数用于将 str[] 字符串复制到 out_num[] 数组。strcpy() 函数将传递给它的第二个字符串复制到第一个字符串中。现在，out_num[] 数组中存在字符串的副本，但只占用数组的 18 个元素，因此数组中仍有 22 个空闲 char 元素。这些空闲元素可以在内存中的字符串之后找到。

该字符串被复制到数组中，以便我们在数组中拥有一些额外的空间，以便在草图的下一部分中使用，即在字符串的末尾添加一个字符串。

将字符串附加到字符串（连接）

该草图将一个字符串连接到另一个字符串，这称为串联。这是使用 strcat() 函数完成的。strcat() 函数将传递给它的第二个字符串放在传递给它的第一个字符串的末尾。

连接后，打印字符串的长度以显示新的字符串长度。然后打印数组的长度，以表明我们在 40 个元素长的数组中有一个 25 个字符长的字符串。

请记住，由于 null 以零结尾，25 个字符的长字符串实际上占用了数组的 26 个字符。

数组界限

使用字符串和数组时，在字符串或数组的范围内工作非常重要。在示例草图中，创建了一个 40 个字符长的数组，以便分配可用于操作字符串的内存。

如果数组太小，并且我们尝试将比数组大的字符串复制到其中，则该字符串将被复制到数组的末尾。数组末尾之外的内存可能包含草图中使用的其他重要数据，这些数据随后将被我们的字符串覆盖。如果超出字符串末尾的内存溢出，则可能会导致草图崩溃或导致意外Behave。