SAS - 饼图

饼图是将值表示为具有不同颜色的圆的切片。切片被标记，并且与每个切片对应的数字也显示在图表中。

在 SAS 中，饼图是使用PROC TEMPLATE创建的，它采用参数来控制百分比、标签、颜色、标题等。

句法

在 SAS 中创建饼图的基本语法是 -

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = variable /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = ' ';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;

以下是所使用参数的描述 -

  • 变量是我们为其创建饼图的值。

简单的饼图

在此饼图中，我们从数据集中采用单个变量。饼图是用代表变量计数相对于变量总值的分数的切片值创建的。

例子

在下面的示例中，每个切片代表汽车类型占汽车总数的比例。

PROC SQL;
create table CARS1 as
SELECT make, model, type, invoice, horsepower, length, weight
 FROM 
SASHELP.CARS
WHERE make in ('Audi','BMW')
;
RUN;

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

当我们执行上面的代码时，我们得到以下输出 -

饼图1

带有数据标签的饼图

在此饼图中，我们表示每个切片的分数值和百分比值。我们还将标签的位置更改为图表内。使用 DATASKIN 选项可以修改图表的外观样式。它使用 SAS 环境中可用的内置样式之一。

例子

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

当我们执行上面的代码时，我们得到以下输出 -

饼图2

分组饼图

在此饼图中，图表中呈现的变量值相对于同一数据集的另一个变量进行分组。每组变成一个圆，图表中的同心圆数量与可用组的数量相同。

例子

在下面的示例中，我们根据名为“Make”的变量对图表进行分组。由于有两个可用值（“奥迪”和“宝马”），因此我们得到两个同心圆，每个同心圆代表自己品牌的汽车类型切片。

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type / Group = make
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

当我们执行上面的代码时，我们得到以下输出 -

饼图3