F# - 模式匹配

---

模式匹配允许您“将数据与逻辑结构进行比较，将数据分解为组成部分，或以各种方式从数据中提取信息”。

换句话说，它提供了一种更灵活、更强大的方法来根据一系列条件测试数据并根据满足的条件执行一些计算。

从概念上讲，它就像一系列 if...then 语句。

句法

在高级术语中，模式匹配在 F# 中遵循以下语法 -

match expr with
| pat1 - result1
| pat2 -> result2
| pat3 when expr2 -> result3
| _ -> defaultResult

在哪里，

• 每个 | 符号定义一个条件。
• -> 符号的意思是“如果条件为真，则返回该值...”。
• _ 符号提供默认模式，这意味着它匹配所有其他内容，例如通配符。

实施例1

以下示例使用模式匹配语法计算斐波那契数 -

let rec fib n =
   match n with
   | 0 -> 0
   | 1 -> 1
   | _ -> fib (n - 1) + fib (n - 2)
for i = 1 to 10 do
   printfn "Fibonacci %d: %d" i (fib i)

当您编译并执行该程序时，它会产生以下输出 -

Fibonacci 1: 1
Fibonacci 2: 1
Fibonacci 3: 2
Fibonacci 4: 3
Fibonacci 5: 5
Fibonacci 6: 8
Fibonacci 7: 13
Fibonacci 8: 21
Fibonacci 9: 34
Fibonacci 10: 55

您还可以将多个条件链接在一起，这些条件返回相同的值。例如 -

实施例2

let printSeason month =
   match month with
   | "December" | "January" | "February" -> printfn "Winter"
   | "March" | "April" -> printfn "Spring"
   | "May" | "June" -> printfn "Summer"
   | "July" | "August" -> printfn "Rainy"
   | "September" | "October" | "November" -> printfn "Autumn"
   | _ -> printfn "Season depends on month!"

printSeason "February"
printSeason "April"
printSeason "November"
printSeason "July"

当您编译并执行该程序时，它会产生以下输出 -

Winter
Spring
Autumn
Rainy

模式匹配函数

F# 允许您使用function关键字编写模式匹配函数-

let getRate = function
   | "potato" -> 10.00
   | "brinjal" -> 20.50
   | "cauliflower" -> 21.00
   | "cabbage" -> 8.75
   | "carrot" -> 15.00
   | _ -> nan (* nan is a special value meaning "not a number" *)

printfn "%g"(getRate "potato")
printfn "%g"(getRate "brinjal")
printfn "%g"(getRate "cauliflower")
printfn "%g"(getRate "cabbage")
printfn "%g"(getRate "carrot")

当您编译并执行该程序时，它会产生以下输出 -

10
20.5
21
8.75
15

向模式添加过滤器或防护

您可以使用when关键字向模式添加过滤器或防护。

实施例1

let sign = function
   | 0 -> 0
   | x when x < 0 -> -1
   | x when x > 0 -> 1

printfn "%d" (sign -20)
printfn "%d" (sign 20)
printfn "%d" (sign 0)

当您编译并执行该程序时，它会产生以下输出 -

-1
1
0

实施例2

let compareInt x =
   match x with
   | (var1, var2) when var1 > var2 -> printfn "%d is greater than %d" var1 var2
   | (var1, var2) when var1 < var2 -> printfn "%d is less than %d" var1 var2
   | (var1, var2) -> printfn "%d equals %d" var1 var2

compareInt (11,25)
compareInt (72, 10)
compareInt (0, 0)

当您编译并执行该程序时，它会产生以下输出 -

11 is less than 25
72 is greater than 10
0 equals 0

元组的模式匹配

以下示例演示了元组的模式匹配 -

let greeting (name, subject) =
   match (name, subject) with
   | ("Zara", _) -> "Hello, Zara"
   | (name, "English") -> "Hello, " + name + " from the department of English"
   | (name, _) when subject.StartsWith("Comp") -> "Hello, " + name + " from the department of Computer Sc."
   | (_, "Accounts and Finance") -> "Welcome to the department of Accounts and Finance!"
   | _ -> "You are not registered into the system"

printfn "%s" (greeting ("Zara", "English"))
printfn "%s" (greeting ("Raman", "Computer Science"))
printfn "%s" (greeting ("Ravi", "Mathematics"))

当您编译并执行该程序时，它会产生以下输出 -

Hello, Zara
Hello, Raman from the department of Computer Sc.
You are not registered into the system

与记录的模式匹配

以下示例演示了与记录的模式匹配 -

type Point = { x: float; y: float }
let evaluatePoint (point: Point) =
   match point with
   | { x = 0.0; y = 0.0 } -> printfn "Point is at the origin."
   | { x = xVal; y = 0.0 } -> printfn "Point is on the x-axis. Value is %f." xVal
   | { x = 0.0; y = yVal } -> printfn "Point is on the y-axis. Value is %f." yVal
   | { x = xVal; y = yVal } -> printfn "Point is at (%f, %f)." xVal yVal

evaluatePoint { x = 0.0; y = 0.0 }
evaluatePoint { x = 10.0; y = 0.0 }
evaluatePoint { x = 0.0; y = 10.0 }
evaluatePoint { x = 10.0; y = 10.0 }

当您编译并执行该程序时，它会产生以下输出 -

Point is at the origin.
Point is on the x-axis. Value is 10.000000.
Point is on the y-axis. Value is 10.000000.
Point is at (10.000000, 10.000000).