Arduino - 湿度传感器

---

在本节中，我们将学习如何将 Arduino 板与不同的传感器连接。我们将讨论以下传感器 -

• 湿度传感器（DHT22）
• 温度传感器（LM35）
• 水检测器传感器（简单水触发器）
• 红外传感器
• 超声波传感器
• 全球定位系统

湿度传感器（DHT22）

DHT-22（也称为 AM2302）是一款数字输出相对湿度和温度传感器。它使用电容式湿度传感器和热敏电阻来测量周围的空气，并在数据引脚上发送数字信号。

在此示例中，您将学习如何将此传感器与 Arduino UNO 结合使用。室温和湿度将打印到串行监视器。

DHT-22 传感器

连接很简单。左侧第一个引脚连接 3-5V 电源，第二个引脚连接数据输入引脚，最右侧引脚连接接地。

技术细节

• 电源- 3-5V

• 最大电流- 2.5mA

• 湿度- 0-100%，2-5% 精度

• 温度− 40 至 80°C，±0.5°C 精度

所需组件

您将需要以下组件 -

• 1 × 面包板
• 1 × Arduino Uno R3
• 1×DHT22
• 1×10K欧姆电阻

程序

按照电路图并将组件连接到面包板上，如下图所示。

草图

在计算机上打开 Arduino IDE 软件。使用 Arduino 语言进行编码将控制您的电路。单击“新建”打开一个新的草图文件。

Arduino代码

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

注意事项代码

DHT22 传感器有四个端子（V _cc、 DATA 、 NC 、 GND ），它们连接到电路板如下 -

• DATA 引脚到 Arduino 引脚 2
• V _cc引脚连接到 Arduino 板的 5 伏电压
• GND 引脚连接到 Arduino 板的地
• 我们需要在DATA和V _cc引脚之间连接10k欧姆电阻（上拉电阻）

硬件连接完成后，您需要将 DHT22 库添加到 Arduino 库文件中，如前所述。

结果

您将在串口监视器上看到温度和湿度显示，每 2 秒更新一次。